狠狠色丁香婷婷综合尤物/久久精品综合一区二区三区/中国有色金属学报/国产日韩欧美在线观看 - 国产一区二区三区四区五区tv

自己寫排序算法十分繁瑣，而且不夠靈活，百度搜索“ASP 文件夾排序”搜到的結果可以100%視為垃圾。本文推薦一種最小代價的做法。

'定義獲取排序文件列表的函數
Function getSortedFiles(folderPath)
    Dim rs, fso, folder, File
    Const adInteger = 3
    Const adDate = 7
    Const adVarChar = 200
    Set rs = Server.CreateObject("ADODB.Recordset")
    Set fso = Server.CreateObject("Scripting.FileSystemObject")
    Set folder = fso.GetFolder(folderPath)
    Set fso = Nothing
    With rs.Fields
        .Append "Name", adVarChar, 200
        .Append "Type", adVarChar, 200
        .Append "DateCreated", adDate
        .Append "DateLastAccessed", adDate
        .Append "DateLastModified", adDate
        .Append "Size", adInteger
        .Append "TotalFileCount", adInteger
    End With
    rs.Open
    For Each File In folder.Files
        rs.AddNew
        rs("Name") = File.Name
        rs("Type") = File.Type
        rs("DateCreated") = File.DateCreated
        rs("DateLastAccessed") = File.DateLastAccessed
        rs("DateLastModified") = File.DateLastModified
        rs("Size") = File.Size
        rs.Update
    Next
    '設置排序規則：按名稱排序
    rs.Sort = "Name ASC"
    ''設置排序規則：依次按文件大小倒序，按修改日期倒序
    'rs.Sort = "Name ASC, Size DESC, DateLastModified DESC"
    rs.MoveFirst
    Set folder = Nothing
    Set getSortedFiles = rs
End Function

'調用函數并輸出結果集
Dim rs
Set rs = getSortedFiles( Server.MapPath("/") )
While Not rs.EOF
    Response.Write "文件信息：" & rs("Name") & " │ " & rs("Type")
    rs.MoveNext
Wend
rs.Close
Set rs = Nothing